home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / gnu / glibc108.gz / glibc108 / glibc-1.08.1 / sysdeps / vax / strstr.s < prev   
Text File  |  1992-05-12  |  4KB  |  114 lines
  1. /*-
  2.  * Copyright (c) 1990 The Regents of the University of California.
  3.  * All rights reserved.
  4.  *
  5.  * Redistribution and use in source and binary forms, with or without
  6.  * modification, are permitted provided that the following conditions
  7.  * are met:
  8.  * 1. Redistributions of source code must retain the above copyright
  9.  *    notice, this list of conditions and the following disclaimer.
  10.  * 2. Redistributions in binary form must reproduce the above copyright
  11.  *    notice, this list of conditions and the following disclaimer in the
  12.  *    documentation and/or other materials provided with the distribution.
  13.  * 3. All advertising materials mentioning features or use of this software
  14.  *    must display the following acknowledgement:
  15.  *    This product includes software developed by the University of
  16.  *    California, Berkeley and its contributors.
  17.  * 4. Neither the name of the University nor the names of its contributors
  18.  *    may be used to endorse or promote products derived from this software
  19.  *    without specific prior written permission.
  20.  *
  21.  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22.  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23.  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24.  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25.  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26.  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27.  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28.  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29.  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30.  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31.  * SUCH DAMAGE.
  32.  */
  33.  
  34. #if defined(LIBC_SCCS) && !defined(lint)
  35.     .asciz "@(#)strstr.s    5.2 (Berkeley) 8/21/90"
  36. #endif /* LIBC_SCCS and not lint */
  37.  
  38. /*
  39.  * Find the first occurrence of s2 as a substring in s1.
  40.  * If s2 is empty, return s1.
  41.  *
  42.  * char *strstr(s1, s2)
  43.  *    const char *s1, *s2;
  44.  */
  45. #include "DEFS.h"
  46.  
  47. ENTRY(strstr, 0)
  48.     movq    4(ap),r3    /* r3 = s1, r4 = s2 */
  49.     movzwl    $65535,r2    /* r2 = locc/matchc limit */
  50.     locc    $0,r2,(r4)    /* find '\0' in s2 */
  51.     beql    4f
  52.     subl3    r4,r1,r5    /* r5 = strlen(s2) */
  53.     beql    1f        /* if r5 == 0, return s1 */
  54.  
  55.     /*
  56.      * s2 is short enough to apply matchc.
  57.      * If s1 is long, we have to do it in stages.
  58.      */
  59. 0:    locc    $0,r2,(r3)    /* find '\0' in s1 */
  60.     beql    3f
  61.  
  62.     /*
  63.      * Both strings are `short'; we can use matchc directly.
  64.      */
  65.     subl3    r3,r1,r1    /* r1 = strlen(s1) */
  66.     matchc    r5,(r4),r1,(r3)    /* find substring */
  67.     bneq    2f
  68.  
  69.     /*
  70.      * r3 points r5 bytes past match.  Return the match.
  71.      */
  72. 1:    subl3    r5,r3,r0    /* return (byte_past_match - strlen(s2)) */
  73.     ret
  74.  
  75.     /*
  76.      * There is no matching substring.
  77.      */
  78. 2:    clrl    r0        /* return NULL */
  79.     ret
  80.  
  81.     /*
  82.      * s1 is too long (> 65535 bytes) to apply matchc directly,
  83.      * but s2 is short enough.  Apply s2 to s1, then (if not
  84.      * found yet) advancing s1 by (65536-strlen(s2)) bytes and
  85.      * loop.
  86.      */
  87. 3:    matchc    r5,(r4),r2,(r3)    /* search */
  88.     beql    1b        /* if found, go return it */
  89.     decw    r2        /* from 0 to 65535 */
  90.     incl    r3        /* already advanced 65535, now 65536 */
  91.     subl2    r5,r3        /* ... minus strlen(s2) */
  92.     brb    0b
  93.  
  94.     /*
  95.      * s2 is too long (> 65535 bytes) to bother with matchc.
  96.      */
  97. 4:    locc    $0,r2,(r1)    /* continue working on strlen(s2) */
  98.     beql    4b
  99.     subl3    r1,r4,r5    /* r5 = strlen(s2) */
  100.     movb    (r4)+,r2    /* r2 = *s2++ */
  101.     decl    r5        /* fix up length */
  102. 5:    movb    (r3)+,r0    /* r0 = *s1++ */
  103.     beql    2b        /* if '\0', return NULL */
  104.     cmpb    r0,r2
  105.     bneq    5b        /* loop until first char found */
  106.     pushr    R5|R4|R3|R2    /* save c, s1, s2, n */
  107.     pushr    R5|R4|R3    /* strncmp(s1, s2, n) */
  108.     calls    $3,_strncmp
  109.     popr    R2|R3|R4|R5    /* restore */
  110.     tstl    r0
  111.     bneq    5b        /* loop until strncmp says rest same too */
  112.     subl3    $1,r3,r0    /* return previous s1 */
  113.     ret
  114.